Re: Job streams in WAIT state - Hewlett Packard

This is a discussion on Re: Job streams in WAIT state - Hewlett Packard ; Looking at this thread it occurred to me that even though OPENQ was mentioned, no one mentioned OPENQ@, to open all queues. Anyway I had this problem before with a system that didn't have a serial line printer, the line ...

+ Reply to Thread
Results 1 to 3 of 3

Thread: Re: Job streams in WAIT state

  1. Re: Job streams in WAIT state

    Looking at this thread it occurred to me that even though OPENQ was mentioned, no one mentioned OPENQ@, to open all queues. Anyway I had this problem before with a system that didn't have a serial line printer, the line printer was networked via NPCONFIG, and a Jetdirect box. So when the system starts up, and the network is not yet started, jobs stay in wait. Additionally, if the network spooled printers are configured to be initially spooled at start up you are in a catch-22, with network errors on the console because the spooler process can't talk to the printers.

    So jobs are in a wait state: Here's what I did:
    Change network spooled printers, to NOT be initially spooled, then when the network is up I xeq the following command file: Which looks into sysgen to find and start all networked printers, printers that have the "HPTCPJD" ID in sysgen, then OPENQ@

    USER DEFINED COMMAND FILE: SPFINIT.UTIL.SYS

    SETVAR HPAUTOCONT TRUE
    # HPPATH must contain HPBIN.SYS
    Echo SPFINIT, Network Printer Process Initialization (MJA) 9/2005.
    Setvar Printer_Count 0
    Setvar START_Count 0
    Setvar Already_Spooled 0
    Setvar _tempmsg 'stdmsg'
    Setvar _tempio 'stdio'
    Setvar hpcierr 0
    Purge !_tempmsg,temp > $null
    Build !_tempmsg;rec=-80,1,f,ascii;temp;msg
    Purge !_tempio,temp > $null
    Build !_tempio;rec=-80,1,f,ascii;temp
    File !_tempmsg=!_tempmsg,oldtemp
    File !_tempio=!_tempio,oldtemp
    #
    SHOWTIME
    Echo Searching for Network Printers
    Purge infile,temp > $null
    Build infile;rec=-80,1,f,ascii;temp
    File xin=infile,oldtemp
    echo io > *xin
    echo ld >> *xin
    Echo exit >> *xin
    Echo exit >> *xin
    Sysgen < *xin > *!_tempmsg
    Setvar _numrecs Finfo('*!_tempmsg','EOF')
    Setvar _LDEV 'INIT'
    Setvar _ID 'INITINIT'
    Setvar _Path 'INITINITINITINIT'
    Setvar _Class 'INITINIT'
    While _numrecs > 0
    Input _stdmsgrec < *!_tempmsg
    Setvar _numrecs (_numrecs-1)
    Setvar _rectype str(_stdmsgrec,1,6)
    Setvar _rectype2 str(_stdmsgrec,6,1)
    If '!_rectype' = ' LDEV:' Then
    Setvar _LDEV str(_stdmsgrec,9,4)
    Endif
    If '!_rectype' = ' ID:' Then
    Setvar _ID str(_stdmsgrec,8,8)
    Endif
    If '!_rectype' = ' PATH:' Then
    Setvar _Path str(_stdmsgrec,8,16)
    Endif
    If '!_rectype' = 'CLASS:' Then
    Setvar _Class str(_stdmsgrec,8,8)
    Endif
    If '!_rectype2' <> ':' Then
    If '!_ID' = 'HPTCPJD ' Then
    XEQ /SYS/UTIL/SPFSTART !_LDEV
    Endif
    Setvar _LDEV 'INIT'
    Setvar _ID 'INITINIT'
    Setvar _Path 'INITINITINITINIT'
    Setvar _Class 'INITINIT'
    Endif
    EndWhile
    Setvar Already_Spooled (Printer_Count - START_Count)
    Echo Spooled Printers: !Printer_Count,
    Echo Spooled Printers Started: !START_Count, already spooled out: !Already_SPooled
    SHOWTIME

    ALSO REQUIRED

    USER DEFINED COMMAND FILE: SPFSTART.UTIL.SYS

    PARM Logical_Device
    Setvar _LD !Logical_Device
    Setvar Printer_Count (!Printer_Count + 1)
    #
    #
    ShowDev !_LD > trashio
    Fgrep "-ic spooler" < trashio > trashout
    Input trashin < trashout
    If '!trashin' = '0'
    Echo StartSpool !_LD
    STARTSPOOL !_LD
    HEADOFF !_LD
    Setvar START_Count (!START_Count + 1)
    Endif
    :


    >>> Jack Connor 10/31/07 2:02 PM >>>

    You may not have done a STARTSPOOL LP...that will cause jobs to wait
    until the $STDLIST device is available.
    jack

    -----Original Message-----
    From: HP-3000 Systems Discussion [mailto:HP3000-L@RAVEN.UTC.EDU] On
    Behalf Of Newton, Ernie
    Sent: Wednesday, October 31, 2007 2:57 PM
    To: HP3000-L@RAVEN.UTC.EDU
    Subject: Re: [HP3000-L] Job streams in WAIT state

    Have you tried issuing the command...STREAMS 10 ?

    This will enable streaming on logical device 10.

    Try it, you'll like it.

    Ernie

    -----Original Message-----
    From: HP-3000 Systems Discussion [mailto:HP3000-L@RAVEN.UTC.EDU] On
    Behalf Of Jim McDermott
    Sent: Wednesday, October 31, 2007 11:30 AM
    To: HP3000-L@RAVEN.UTC.EDU
    Subject: [HP3000-L] Job streams in WAIT state

    Hello all:

    This is a real quick question concerning jobs that are in the WAIT state
    after installing MPE/iX 6.0 from a CSLT for a Disaster Recovery
    exercise. After system is installed, I have tried to stream a job that
    builds the volumes/volume sets but it just goes into a WAIT state. In
    fact, any job I try streaming has the same problem. I'm logged on as
    MANAGER.SYS and job limit is set to 13 in jobstream. I tried HIPRI but
    nothing works. I wind up having to manually issue the commands to do
    the builds and after a reboot, the scheduler has no problem for
    streaming thereafter. Is there a command that I need to issue?
    Please help because I'm doing another DR exercise soon for a client.
    Thanks.

    * To join/leave the list, search archives, change list settings, *
    * etc., please visit http://raven.utc.edu/archives/hp3000-l.html *

    The Yolo County Office of Education has scanned this message for viruses
    and dangerous content

    * To join/leave the list, search archives, change list settings, *
    * etc., please visit http://raven.utc.edu/archives/hp3000-l.html *

    * To join/leave the list, search archives, change list settings, *
    * etc., please visit http://raven.utc.edu/archives/hp3000-l.html *

    * To join/leave the list, search archives, change list settings, *
    * etc., please visit http://raven.utc.edu/archives/hp3000-l.html *


  2. Re: Job streams in WAIT state

    Michael wrote...

    > So jobs are in a wait state: Here's what I did: Change network
    > spooled printers, to NOT be initially spooled, then when the network
    > is up I xeq the following command file: Which looks into sysgen to
    > find and start all networked printers, printers that have the
    > "HPTCPJD" ID in sysgen, then OPENQ@


    "which looks into sysgen" ... interesting approach

    For what it's worth... an alternate approach that I typically used...
    instead of invoking SYSGEN and parsing the output... I made all network
    printers member of a dedicated device class like "NETLP" (in addition
    to whatever individual classes were used per LDEV) and thus got a handy
    way to "select" them in SHOWDEV or spooler commands ;-)

    Cheers, Lars.

    * To join/leave the list, search archives, change list settings, *
    * etc., please visit http://raven.utc.edu/archives/hp3000-l.html *


  3. Re: Job streams in WAIT state

    On 11/1/07, Lars Appel wrote:
    >
    > "which looks into sysgen" ... interesting approach
    >
    > For what it's worth... an alternate approach that I typically used...
    > instead of invoking SYSGEN and parsing the output... I made all network
    > printers member of a dedicated device class like "NETLP" (in addition
    > to whatever individual classes were used per LDEV) and thus got a handy
    > way to "select" them in SHOWDEV or spooler commands ;-)


    i do something quite similar....giving network printers a common class
    name so that i can easily assure that they're all spooled following a
    reboot.

    of course....at this point, i've filled up two of these common class
    name and am working on my 3rd 8-} - d 'why yes, i think a
    n-class box makes a f-i-n-e print server'

    * To join/leave the list, search archives, change list settings, *
    * etc., please visit http://raven.utc.edu/archives/hp3000-l.html *


+ Reply to Thread